new: extract logging module into standalone core library

core/logging/build.gradle.kts

@@ -0,0 +1,49 @@
+import org.jetbrains.kotlin.gradle.ExperimentalWasmDsl
+import org.jetbrains.kotlin.gradle.dsl.JvmTarget
+
+plugins {
+    alias(libs.plugins.kotlinMultiplatform)
+    alias(libs.plugins.androidMultiplatformLibrary)
+}
+
+kotlin {
+    iosArm64()
+    iosSimulatorArm64()
+
+    jvm()
+
+    js {
+        browser()
+    }
+
+    @OptIn(ExperimentalWasmDsl::class)
+    wasmJs {
+        browser()
+    }
+
+    androidLibrary {
+        namespace = "fr.ajaury.gwenedeg.core.logging"
+        compileSdk =
+            libs.versions.androidCompileSdk
+                .get()
+                .toInt()
+        minSdk =
+            libs.versions.androidMinSdk
+                .get()
+                .toInt()
+
+        compilerOptions {
+            jvmTarget = JvmTarget.JVM_11
+        }
+    }
+
+    sourceSets {
+        commonMain.dependencies {
+            // Logging
+            implementation(libs.kermit)
+        }
+        commonTest.dependencies {
+            implementation(libs.kotlin.test)
+        }
+    }
+}

settings.gradle.kts

@@ -36,4 +36,7 @@ include(":androidApp")
 include(":desktopApp")
 include(":webApp")
 include(":shared")
+
+// Core modules
 include(":core:audioplayer")
+include(":core:logging")

shared/build.gradle.kts

@@ -58,8 +58,9 @@ kotlin {
             implementation(libs.compose.uiToolingPreview)
         }
         commonMain.dependencies {
-            // Audio player module
+            // Core modules
             implementation(projects.core.audioplayer)
+            implementation(projects.core.logging)
 
             implementation(libs.compose.runtime)
             implementation(libs.compose.foundation)
@@ -69,9 +70,6 @@ kotlin {
             implementation(libs.compose.components.resources)
             implementation(libs.compose.uiToolingPreview)
 
-            // Logging
-            implementation(libs.kermit)
-
             // Lifecycle
             implementation(libs.lifecycle.viewmodelCompose)
             implementation(libs.lifecycle.runtimeCompose)