new: introduce build-logic module to centralize Gradle configuration

build-logic/build.gradle.kts

@@ -0,0 +1,13 @@
+plugins {
+    `kotlin-dsl`
+}
+
+dependencies {
+    implementation(libs.android.gradlePlugin)
+    implementation(libs.kotlin.gradlePlugin)
+    implementation(libs.compose.gradlePlugin)
+    implementation(libs.composeCompiler.gradlePlugin)
+    // Makes the typed `libs` catalog accessors usable inside precompiled script plugins
+    // (workaround for https://github.com/gradle/gradle/issues/15383)
+    implementation(files(libs.javaClass.superclass.protectionDomain.codeSource.location))
+}

build-logic/settings.gradle.kts

@@ -0,0 +1,20 @@
+rootProject.name = "build-logic"
+
+dependencyResolutionManagement {
+    repositories {
+        google {
+            mavenContent {
+                includeGroupAndSubgroups("androidx")
+                includeGroupAndSubgroups("com.android")
+                includeGroupAndSubgroups("com.google")
+            }
+        }
+        mavenCentral()
+        gradlePluginPortal()
+    }
+    versionCatalogs {
+        create("libs") {
+            from(files("../gradle/libs.versions.toml"))
+        }
+    }
+}

build-logic/src/main/kotlin/gwenedeg.compose.gradle.kts

@@ -0,0 +1,4 @@
+plugins {
+    id("org.jetbrains.compose")
+    id("org.jetbrains.kotlin.plugin.compose")
+}

build-logic/src/main/kotlin/gwenedeg.kmp.library.gradle.kts

@@ -0,0 +1,48 @@
+import org.gradle.accessors.dm.LibrariesForLibs
+import org.jetbrains.kotlin.gradle.ExperimentalWasmDsl
+import org.jetbrains.kotlin.gradle.dsl.JvmTarget
+
+plugins {
+    id("org.jetbrains.kotlin.multiplatform")
+    id("com.android.kotlin.multiplatform.library")
+}
+
+val libs = the<LibrariesForLibs>()
+
+kotlin {
+    iosArm64()
+    iosSimulatorArm64()
+
+    jvm()
+
+    js {
+        browser()
+    }
+
+    @OptIn(ExperimentalWasmDsl::class)
+    wasmJs {
+        browser()
+    }
+
+    androidLibrary {
+        // namespace is set per module in the consuming build file
+        compileSdk =
+            libs.versions.androidCompileSdk
+                .get()
+                .toInt()
+        minSdk =
+            libs.versions.androidMinSdk
+                .get()
+                .toInt()
+
+        compilerOptions {
+            jvmTarget = JvmTarget.JVM_11
+        }
+    }
+
+    sourceSets {
+        commonTest.dependencies {
+            implementation(libs.kotlin.test)
+        }
+    }
+}